Originalmente publicado por juanjo_16v
Ver Mensaje
@echo off
pushd "%cd%"
cd /d "%~dp0"
if NOT "%cd%"=="%cd: =%" (
echo EL directorio del script tiene espacios en su path.
echo.
pause
goto :EOF
)
popd
if "[%1]" == "[49127c4b-02dc-482e-ac4f-ec4d659b7547]" goto :START_PROCESS
REG QUERY HKU\S-1-5-19\Environment >NUL 2>&1 && goto :START_PROCESS
set command="""%~f0""" 49127c4b-02dc-482e-ac4f-ec4d659b7547
setlocal enabledelayedexpansion
set "command=!command:'=''!"
powershell -NoProfile Start-Process -FilePath '%COMSPEC%' ^
-ArgumentList '/c """!command!"""' -Verb RunAs 2>NUL
IF %ERRORLEVEL% GTR 0 (
echo ================================================== ====
echo Este script necesita ejecutarse como un Administrador.
echo ================================================== ====
echo.
pause
)
goto :EOF
:START_PROCESS
setlocal enabledelayedexpansion
if not exist "%temp%" md "%temp%"
set file=%temp%\%random%.wsl.tmp
tasklist >%file%
for /f "usebackq tokens=1,2 delims= " %%a in (`tasklist`) do if /i {%%a} EQU {wsl.exe} call :kill wsl.exe %%b
for /f "usebackq tokens=1,2 delims= " %%a in (`tasklist`) do if /i {%%a} EQU {wslservice.exe} call :kill wslservice.exe %%b
timeout /T 4 /NOBREAK >nul
echo Restore WSL
>nul sc start wslservice 2>&1
timeout /T 3 /NOBREAK >nul
wsl --shutdown
rundll32.exe cmdext.dll,MessageBeepStub
echo.
set /P x=[Pulse para finalizar]
goto :EOF
:kill
echo kill %1: PID %2
>nul taskkill /PID %2 /T /F 2>&1
timeout /T 1 /NOBREAK >nul
goto :EOF
Dejar un comentario: