[TIP] Script para ver los recursos y puertos asignados en los contenedores para LXD

[jmtella]

Para los que hayan seguido los artículos de LXD (en este orden)

[TIP] Ejercicio: Multipass y LXD

[TIP] WSL 2 y LXD

[TIP] Creando y usando imagenes con LXC

[TIP] Scripts de asignación LXC a las imagenes de los contenedores LXD

Lo normal, al menos yo, es vbolverse vicioso de los contendores y usarlos para casi todo. EL problema surge cuando queremos saber que recirsos hemos asignado a cada contenedor, y no suele mas remedio que o bien apuntarlo... o bien ir contenedor por contenedor en cada instancia para verlo.

Por ejemplo, en mi caso, los contendores que tengo ahora en ejecución son:



He preparado un script que nos muestra los puertos asignados a una instancia de las anteriores:

@echo off
setlocal enabledelayedexpansion

set ip=
for /f "usebackq tokens=1,3 delims=,:/" %%n in (`lxc remote list --format csv`) do if %%n EQU %1 set ip=%%o
REM echo !ip!
if {!ip!} EQU {} (
   echo Instancia no encontrada
   rundll32.exe cmdext.dll,MessageBeepStub
   exit /b
)

echo.
call :ColorText 0A %1
echo [!ip!]

for /f "usebackq tokens=1" %%n in (`lxc list -c n --format csv %1:`) do call :dev %1 %%n
exit /b

:dev
echo.
call :ColorText 0C %1
echo %2
for /f "usebackq tokens=1* delims=" %%a in (`lxc config device show %1:%2`) do echo %%a
exit /b

:ColorText [%1 = Color] [%2 = Text]
pushd "%temp%"
set /P ".= ->" > "%~2" <nul
findstr /v /a:%1 /R "^$" "%~2" nul 2>&1
if "%3"=="end" echo.
del "%~2">nul 2>&1
popd
exit /b

La he guardad con el nombre devices-lxc.cmd. Espera un parámetro que es el nombre de instancia.